Les Panama Papers

MATCH (n:Entity) RETURN count(*);
MATCH (n:Officer) RETURN count(*);
MATCH (n:Intermediary) RETURN count(*);
MATCH (n:Address) RETURN count(*);

MATCH (i:Intermediary) WHERE size( (i)--() ) > 100
MATCH (i)-[:INTERMEDIARY_OF]->(entity:Entity)
RETURN i.name as intermediary, count(*) as count
ORDER BY count DESC LIMIT 20

MATCH (i:Intermediary)-[r:INTERMEDIARY_OF]->(e:Entity)
WHERE i.name CONTAINS "MOSSACK FONSECA"
RETURN i, r, e LIMIT 100

MATCH (o:Officer)-->(e:Entity)<-[:INTERMEDIARY_OF]-(i:Intermediary)
WHERE o.country_codes CONTAINS 'FRA'
RETURN e.jurisdiction_description AS jurisdiction, count(*) AS number
ORDER BY number DESC LIMIT 10

MATCH (a:Address)<-[:REGISTERED_ADDRESS]-(o:Officer),
(o)-->(e:Entity)<-[:INTERMEDIARY_OF]-(i:Intermediary)
WHERE a.address CONTAINS 'Paris' AND a.address CONTAINS 'France'
RETURN i.name AS intermediary, count(DISTINCT e) AS number
ORDER BY number DESC LIMIT 10

MATCH (o1:Officer)-[r1]->(e:Entity)<-[r2]-(o2:Officer)
WHERE id(o1) < id(o2)
AND size( (o1)-->() ) > 2 AND size( (o2)-->() ) > 2
WITH o1,o2, count(*) as freq, collect(e.name)[0..10] as entities
WHERE freq > 2
RETURN o1.name, o2.name, freq, entities
ORDER BY freq DESC
LIMIT 10

MATCH (a:Officer),(b:Officer)
WHERE a.name CONTAINS 'Smith'
  AND b.name CONTAINS 'Grant'
MATCH p=allShortestPaths((a)-[:OFFICER_OF|:INTERMEDIARY_OF|:REGISTERED_ADDRESS*..10]-(b))
RETURN p
LIMIT 50